Ultima Online Antares

; Качаем форенсик на ближайшем трупе до тех пор пока он не исчезнет
sub ForensicOnNearCorpse()
    UO.WarMode(False)
    var StartTime   = Now()
    var Corpse      = UO.FindList('Corpses', 'ground', LootDist, -1, -1)

    UO.DeleteJournal()
    var timeout = 3700
    var StartIterationTime = Now()
    repeat
        Corpse = UO.FindList('Corpses', 'ground', LootDist, -1, -1)
        
        if not Corpse <> '' then
            Uo.Print('Труп пропал выходим')
            return
        end if
    
        if UO.WarMode() then
            UO.WarMode(False)
        end if
        StartIterationTime = Now()
        uo.WaitTargetObject(Corpse)
        UO.UseSkill('Forensic Evaluation')
        wait(2300)
        if UO.InJournalBetweenTimes("You must wait to perform", StartIterationTime) then
            timeout=timeout + 10
        else
    ;    timeout=timeout - 10
        end if
    until UO.Dead() ||  UO.InJournalBetweenTimes("see the target", StartTime)
    uo.print('в конце таймаут=' + Str(timeout))
end sub

; качаем форенсик. Использует скрипты зомби пака. Как работает:
; делает рекол по рунам из массива должны лежать в паке
; находит ламу рядом уюивает ее и качает на ее трупе форенсик
; труп лежит 300сек , далее повторяет процедуру по всем рунам из массива
; и так пока не умерт
sub MyForensicLoop()
    var RunesCount = 7
    dim LlamaRunes[Val(Str(RunesCount))]
    LlamaRunes[0]    = '0x403AC9CC'
    LlamaRunes[1]    = '0x4026EF5C'
    LlamaRunes[2]    = '0x403AC9CD'
    LlamaRunes[3]    = '0x4026EF5E'
    LlamaRunes[4]    = '0x40DF27BE'
    LlamaRunes[5]    = '0x401FEA6B'
    LlamaRunes[6]    = '0x40781C47';trinsic
    
    var Index
    var LlamaRune
    var Rune
    var Serial
    var Hp
    var StartTime   = Now()
    var LlamaColor    = 0x0000
    var LlamaType    = 0x00DC
    
    while not UO.Dead()
        for Index = 0 to RunesCount - 1
            RecallRune(LlamaRunes[Index])
            Meditation()
            Wait(2000)
            
        ;ищем живку
            if not UO.FindType(LlamaType, LlamaColor, 'ground', 3) <> '' then
                Uo.Print('Живка отсутствует го дальше, подождем сначала 60сек')
                Wait(60000)
                continue
            end if
        ;убиваем живку
            Serial = UO.GetSerial('finditem')
            if not UO.WarMode() then
                UO.WarMode(True)
            end if
            UO.Attack(Serial)
            Wait(4000)
            StartTime = Now()
            repeat
                Hp = UO.GetHP(Serial)
                Uo.Print('MyForensicLoop : ждемс ща убьет, осталость [' + Str(Hp) + '] Hp')
                Wait(1000)
            until UO.Dead() || Hp == 0
            
        ;качаем форенсик на трупе
            ForensicOnNearCorpse()
        next
    wend

    
end sub

Sub RecallRune(RuneSerial)
   UO.WarMode(False)
   CastBook(RuneSerial, 'Recall', 12, BP, BM, MR, MR)
   WaitForCast(CastDelay(1))
end sub

sub SkillsUp()
    Evaluating()
    SpiritSpeak()
    TasteIdentification()
    ItemIdentification()
    ArmsLore()
end sub

sub Evaluating()
    UO.DeleteJournal()
    uo.print('Evaluating : skillVal=' + Str(UO.SkillVal('Evaluate Intelligence', 1)))
    while not uo.dead() and UO.SkillVal('Evaluate Intelligence', 1) < 1000
        Cheklag()
        UO.UseSkill('Evaluating Intelligence', 'self')
        UO.WaitingForJournalText(Now(), 5000, "seem")
        UO.DeleteJournal()
    wend
end sub

sub SpiritSpeak()
    UO.DeleteJournal()
    uo.print('SpiritSpeak : skillVal=' + Str(UO.SkillVal('Spirit Speak', 1)))
    while not uo.dead() and UO.SkillVal('Spirit Speak', 1) < 1000
        Cheklag()
        UO.UseSkill('Spirit Speak')
        repeat
            wait(200)
        until UO.InJournal('fail') or UO.InJournal('establish')
        UO.DeleteJournal()
    wend
end sub

sub TasteIdentification()
    var Type     = 0x09D0;apple
    var Color     = 0x0000;
    var Skill     = 'Taste Identification'

    UO.DeleteJournal()
    uo.print('TasteIdentification : skillVal=' + Str(UO.SkillVal(Skill, 1)))
    while not uo.dead() and UO.SkillVal(Skill, 1) < 1000
        Cheklag()
        if not UO.FindType(Type, Color, 'backpack') <> '' then
            UO.ColorPrint(0x0026, 'Нет предмета для проверки')
            return
        end if
        
        UO.WaitTargetObject('finditem')
        UO.UseSkill(Skill)
        UO.WaitingForJournalText(Now(), 3000, "cannot")
        UO.DeleteJournal()
    wend
end sub

sub ItemIdentification()
    var Type             = 0x0EFA;spellbook
    var Color             = 0x0000;
    var InjectSkill     = 'Item ID'
    var Skill             = 'Item Identification'

    UO.DeleteJournal()
    uo.print( Skill + ' has val=' + Str(UO.SkillVal(InjectSkill, 1)))
    while not uo.dead() and UO.SkillVal(InjectSkill, 1) < 1000
        Cheklag()
        if not UO.FindType(Type, Color, 'backpack') <> '' then
            UO.ColorPrint(0x0026, 'Нет предмета для проверки')
            return
        end if
        
        UO.WaitTargetObject('finditem')
        UO.UseSkill(Skill)
        UO.WaitingForJournalText(Now(), 3000, "anything")
        UO.DeleteJournal()
    wend
end sub

sub ArmsLore()
    var Type             = 0x0F51;dagger
    var Color             = 0x0000;
    var Skill             = 'Arms Lore'

    UO.DeleteJournal()
    uo.print( Skill + ' has val=' + Str(UO.SkillVal(Skill, 1)))
    while not uo.dead() and UO.SkillVal(Skill, 1) < 1000
        Cheklag()
        if not UO.FindType(Type, Color, 'backpack') <> '' then
            UO.ColorPrint(0x0026, 'Нет предмета для проверки')
            return
        end if
        
        UO.WaitTargetObject('finditem')
        UO.UseSkill(Skill)
        UO.WaitingForJournalText(Now(), 3000, "uncertain")
        UO.DeleteJournal()
    wend
end sub