Ultima Online Antares

;----------------------------------------------------------------------------
; by VeL                                                            The Best
;----------------------------------------------------------------------------

var Count       = 100

var BP          = 0x0F7A       ; Bleack Pearl
var BM          = 0x0F7B       ; Blood Moss
var MR          = 0x0F86       ; Mandrake Root
var NS          = 0x0F88       ; Nightshade
var SS          = 0x0F8D       ; Spider Silk
var SA          = 0x0F8C       ; Sulphurous Ash
var GA          = 0x0F84       ; Garlic
var GI          = 0x0F85       ; Ginseng

var BlankScroll = 0x0E34       ; тип чистых свитков "Blank Scrolls"
var Tool        = 0x0FBF       ; тип инструмента "Pen and Ink"

;--------------------------------------------------------
; Изготовление свитков
;--------------------------------------------------------

sub Heal()
  return CraftScrolls(1, 'Heal', 0x1F31, GI, NS, NS, NS)
end sub

sub Harm()
  return CraftScrolls(2, 'Harm', 0x1F38, NS, SS, SS, SS)
end sub

sub SummonCreature()
  return CraftScrolls(5, 'Summon Creature', 0x1F54, BM, MR, SS, SS)
end sub

Sub CraftScrolls(Circle, Name, Type, Reg1, Reg2, Reg3, Reg4)

  UO.ColorPrint(0x042B, 'Изготавливаем "' + Name + '" ' + str(Count) + 'шт.')

  while UO.Count(Type, 0x0000) < Count
    if not Inscription(Name, Circle, Reg1, Reg2, Reg3, Reg4) then
      UO.ColorPrint(0x0026, '- изготовлено "' + Name + '" ' + Str(UO.Count(Type, 0x0000)) + 'шт.')
      return False
    end if
  wend

  UO.ColorPrint(0x042B, 'Изготовление "' + Name + '" завершено.')
  return True

end sub

Sub Inscription(Name, Circle, Reg1, Reg2, Reg3, Reg4)

dim Circles[8]
    Circles[1]  = 'First'
    Circles[2]  = 'Second'
    Circles[3]  = 'Third'
    Circles[4]  = 'Fourth'
    Circles[5]  = 'Fifth'
    Circles[6]  = 'Sixth'
    Circles[7]  = 'Seventh'
    Circles[8]  = 'Eight'

dim Mana[8]
    Mana[1]     = 6
    Mana[2]     = 8
    Mana[3]     = 10
    Mana[4]     = 12
    Mana[5]     = 16
    Mana[6]     = 20
    Mana[7]     = 30
    Mana[8]     = 40

  if UO.Count(Tool) == 0 then
    UO.ColorPrint(0x0026, 'Инструмент не найден!')
    return False
  end if

  if UO.Count(BlankScroll) < 1 then
    UO.ColorPrint(0x0026, 'Нет чистых свитков!')
    return False
  end if

  if UO.Count(Reg1) < 1 || UO.Count(Reg2) < 1 || UO.Count(Reg3) < 1 || UO.Count(Reg4) < 1 then
    UO.ColorPrint(0x0026, 'Недостаточно реагентов!')
    return False
  end if

  if UO.Mana < Mana[Circle] then
    Meditation(UO.Int)
  end if

  UO.WaitMenu('Spell Circles', Circles[Circle] + ' Circle', 'Spell Circle ' + Str(Circle), Name)
  UO.UseType(BlankScroll)
  UO.WaitingForJournalText(Now(), 60000, 'You put|You fail|Unexpected|destroyed!')
  Wait(50)

  return True

end sub

Sub Meditation(Mana)

  while UO.Mana < Mana
    UO.ColorPrint(0x042B, 'Медитируем.')
    UO.DeleteJournal()
    UO.UseSkill('Meditation')
    repeat
      Wait(300)
    until UO.InJournal('You are at peace.|You lose') or (UO.Mana >= Mana)
  wend

end sub